mirror of
https://github.com/TECHNOFAB11/kubenix.git
synced 2025-12-12 16:10:05 +01:00
6183fcc190
- Support for module features - Remove kubenix.module and rather use explicit modules - Make tests framework independent of k8s module - Remove metacontroller submodule, which will go to kubenix-modules - Improved submodule propagation and passthru - Added additional test for k8s-submodule
43 lines
1.2 KiB
Nix
43 lines
1.2 KiB
Nix
{ lib, pkgs }:
|
|
|
|
with lib;
|
|
|
|
rec {
|
|
moduleToAttrs = value:
|
|
if isAttrs value
|
|
then mapAttrs (n: v: moduleToAttrs v) (filterAttrs (n: v: !(hasPrefix "_" n) && v != null) value)
|
|
|
|
else if isList value
|
|
then map (v: moduleToAttrs v) value
|
|
|
|
else value;
|
|
|
|
mkAllDefault = value: priority:
|
|
if isAttrs value
|
|
then mapAttrs (n: v: mkAllDefault v priority) value
|
|
|
|
else if isList value
|
|
then map (v: mkAllDefault v priority) value
|
|
|
|
else mkOverride priority value;
|
|
|
|
loadYAML = path: importJSON (pkgs.runCommand "yaml-to-json" {
|
|
} "${pkgs.remarshal}/bin/remarshal -i ${path} -if yaml -of json > $out");
|
|
|
|
toYAML = config: pkgs.runCommand "to-yaml" {
|
|
buildInputs = [pkgs.remarshal];
|
|
} ''
|
|
remarshal -i ${pkgs.writeText "to-json" (builtins.toJSON config)} -if json -of yaml > $out
|
|
'';
|
|
|
|
toBase64 = value:
|
|
builtins.readFile
|
|
(pkgs.runCommand "value-to-b64" {} "echo -n '${value}' | ${pkgs.coreutils}/bin/base64 -w0 > $out");
|
|
|
|
exp = base: exp: foldr (value: acc: acc * base) 1 (range 1 exp);
|
|
|
|
octalToDecimal = value: (foldr (char: acc: {
|
|
i = acc.i + 1;
|
|
value = acc.value + (toInt char) * (exp 8 acc.i);
|
|
}) {i = 0; value = 0;} (stringToCharacters value)).value;
|
|
}
|