technofab/disko
1
0
Fork 0
mirror of https://github.com/TECHNOFAB11/disko.git synced 2025-12-11 23:50:05 +01:00
Code Issues Projects Releases Packages Wiki Activity Actions

split disko type into multiple files

Browse source
This commit is contained in:
Jörg Thalheim 2023-01-28 16:19:13 +01:00
parent aa26c0ce0d
commit 48e4c06004
21 changed files with 1595 additions and 3 deletions
Download patch file Download diff file Expand all files Collapse all files

63
types/table.nix Normal file
View file

@ -0,0 +1,63 @@
{ config, options, lib, diskoLib, subTypes, ... }:
{
options = {
type = lib.mkOption {
type = lib.types.enum [ "table" ];
internal = true;
description = "Partition table";
};
format = lib.mkOption {
type = lib.types.enum [ "gpt" "msdos" ];
default = "gpt";
description = "The kind of partition table";
};
partitions = lib.mkOption {
type = lib.types.listOf subTypes.partition;
default = [ ];
description = "List of partitions to add to the partition table";
};
_meta = lib.mkOption {
internal = true;
readOnly = true;
type = lib.types.functionTo diskoLib.jsonType;
default = dev:
diskoLib.deepMergeMap (partition: partition._meta dev) config.partitions;
description = "Metadata";
};
_create = diskoLib.mkCreateOption {
inherit config options;
default = { dev }: ''
parted -s ${dev} -- mklabel ${config.format}
${lib.concatMapStrings (partition: partition._create {inherit dev; type = config.format;} ) config.partitions}
'';
};
_mount = diskoLib.mkMountOption {
inherit config options;
default = { dev }:
let
partMounts = diskoLib.deepMergeMap (partition: partition._mount { inherit dev; }) config.partitions;
in
{
dev = ''
${lib.concatMapStrings (x: x.dev or "") (lib.attrValues partMounts)}
'';
fs = partMounts.fs or { };
};
};
_config = lib.mkOption {
internal = true;
readOnly = true;
default = dev:
map (partition: partition._config dev) config.partitions;
description = "NixOS configuration";
};
_pkgs = lib.mkOption {
internal = true;
readOnly = true;
type = lib.types.functionTo (lib.types.listOf lib.types.package);
default = pkgs:
[ pkgs.parted pkgs.systemdMinimal ] ++ lib.flatten (map (partition: partition._pkgs pkgs) config.partitions);
description = "Packages";
};
};
}