coder-templates/image.nix

{
  lib,
  pkgs,
  ...
}:
pkgs.dockerTools.buildLayeredImage {
  name = "nix-coder";
  tag = "latest";

  contents = pkgs.buildEnv {
    name = "image-root";
    paths = with pkgs; [
      bash
      bashInteractive
      nix
      coreutils-full
      openssh
      git
      curl
      ncurses
      dockerTools.usrBinEnv
      (writeShellScriptBin "reload-dotfiles" ''
        ${home-manager}/bin/home-manager switch --flake ''${DOTFILES_REPO:-$1}
      '')
      (writeTextDir "etc/nix/nix.conf" ''
        experimental-features = nix-command flakes
      '')
      (writeTextDir "etc/os-release" ''
        ID=nixos
      '')
      (writeTextDir "etc/passwd" "coder:x:1000:1000::/home/coder:/bin/bash")
      (writeTextDir "etc/shadow" "coder:!:::::::")
      (writeTextDir "etc/group" "coder:x:1000:")
      (writeTextDir "etc/gshadow" "coder:x::")
    ];
    pathsToLink = ["/bin" "/etc" "/usr"];
  };
  maxLayers = 5;

  uid = 1000;
  gid = 1000;
  fakeRootCommands = ''
    mkdir -p ./home/coder ./tmp ./nix/var/nix
    chown -R 1000:1000 ./
  '';

  config = {
    Cmd = ["/bin/bash"];
    User = "1000:1000";
    Env = [
      "SSL_CERT_FILE=${pkgs.cacert}/etc/ssl/certs/ca-bundle.crt"
      "HOME=/home/coder"
      "USER=coder"
    ];
  };
}